As has been remarked earlier, if you take an unbounded potential $V(x)$ (so that all the eigenstates are bound) and you look at the uncertainty product $\Delta x\Delta p$ as a function of the index $n$ of the eigenstate, then for the two usual unbounded potentials (the simple harmonic oscillator and the infinite square well) $\Delta x\Delta p$ grows linearly with $n$.
How does this product behave for other solvable potentials, such as the linear cone potential $V(x)=|x|$?
The cone potential $V(x)$ is exactly solvable, with eigenstates of the form $$ \psi(x)\propto\mathrm{Ai}(|x|-b) $$ in terms of the Airy $\mathrm{Ai}$ function, so this is rather easy to test. It is probably possible to produce explicit analytic expressions for the uncertainty product, but simple numerical evidence is plenty to see the behaviour here. Mathematica has most of it already implemented, and the rest is details.
Thus, if one sets
ψ[n_?EvenQ, x_] := AiryAi[Sqrt[x^2] + b[n]]/(Sqrt[-2 b[n]] AiryAi[b[n]])
b[n_?EvenQ] := x /. FindRoot[AiryAiPrime[x], {x,
-(3 Pi/8 (Max[0, 2 n - 1]))^(2/3), -(3 Pi/8 (2 n + 3))^(2/3)}]
ψ[n_?OddQ, x_] := Sign[x] AiryAi[Sqrt[x^2] + AiryAiZero[(n + 1)/2]]/(
Sqrt[2] AiryAiPrime[AiryAiZero[(n + 1)/2]])
b[n_?OddQ] := AiryAiZero[(n + 1)/2]
with $\psi_n(x)$ set to a properly normalized wavefunction of the form $\mathrm{Ai}(|x|-b)$ with $b$ set to a zero of the Airy function of its derivative, then the eigenfunctions are obviously right,
Plot[
Evaluate[Join[{Abs[x]},
Table[-b[n] + 0.7 ψ[n, x], {n, 0, 16}]
]]
, {x, -12, 12}
, Frame -> True
, Axes -> False
, ImageSize -> 700
, PlotRangePadding -> None
]
and can be checked to be normalized using
Table[NIntegrate[ψ[n, x]^2, {x, -∞, ∞}], {n, 0, 25}]
The uncertainty product can be integrated numerically, via
Table[{n, Sqrt[
NIntegrate[x^2 ψ[n, x]^2, {x, -∞, ∞}]
NIntegrate[Evaluate[
-D[ψ[n, x], {x, 2}] /. {Sign'[_] -> 0, Sign''[_] -> 0}]
ψ[n, x], {x, -∞, ∞}]]}
, {n, 0, 25}];
and it looks like this,
i.e. obviously very, very linear. (As an interesting aside, the ground state obviously satisfies the uncertainty principle, at $\Delta x\Delta p = 0.50463\cdots$, but as a plus it is also rather close to the minimal value.)
Just for fun, let's try another analytically-solvable potential, the exponential potential $$V(x)=A\exp(x),$$ bound on the left by the condition $\psi(0)=0$. The eigenfunctions of this problem are derived in the linked question to be of the form $$\psi_n(x)=C_nK_{2i\sqrt{E_n}}\left(2\sqrt{A}e^{x/2}\right),$$ where the quantization condition forces the energies $E_n$ to obey the equation $$K_{2i\sqrt E}(2\sqrt{A})=0.$$ This is relatively straightforward to code, using
ψ[e_, A_, x_] := Sqrt[2 Sqrt[e] Sinh[2 π Sqrt[e]]]
BesselK[2 I Sqrt[e], 2 Sqrt[A] Exp[x/2]]
and the spectrum via
getSpectrum[A_, max_: 200] :=
getSpectrum[A, max] = getSpectrum[A] = Sort[
Re[e] /.
FindComplexRoots[
BesselK[2 I Sqrt[e], 2 Sqrt[A]] == 0, {e, 0 - 0.1 I,
max + 0.1 I}, SeedGenerator -> RandomSobolComplexes,
Tolerance -> 10^-5]
]
using the FindComplexRoots function from this package, documented here, giving wavefunctions that look something like
for $A=1$, and with the uncertainty products being numerically integrable using
Column@AbsoluteTiming[
data = Table[
Sqrt[NIntegrate[x^2 f^2, {x, 0, ∞}] -
NIntegrate[x f^2, {x, 0, ∞}]^2] Sqrt[
NIntegrate[D[f, x]^2, {x, 0, ∞}] -
NIntegrate[x f^2, {x, 0, ∞}]^2]
, {f, (ψ[getSpectrum[1, 200], 1, x]/norm[1])[[1 ;; 15]]}]
]
looking like
which is again very linear.
